*effectsize_fixed.sps.
*title "90% confidence intervals of effect size (fixed effects ANOVA)".
*  effect size index f=.
* small f=.10 : medium f=.25: large f=.40  Cohen(1988).
* Steiger and Fouladi(1997) in Harlow, Mulaik and Steiger(eds)
*   What if there were no significance tests? LEA.
preserve.
set printback=none.
set mxloops=1000000.
data list free/ alpha fvalue dfh dfe n npc.

begin data
 0.05  0.36   1  54 60 30 
 0.05  209.66 2  54 60 20
 0.05  34.01  2  54 60 10
 0.05  11.2212 4 50 55 11 
 0.05  0.82    1 116 120 60
 0.05  32.21   1 116 120 60
 0.05  16.84   1 116 120 30
 0.05  6.00   1 42 56 28
 0.05  2.65   6 42 56 0
 0.05  2.50   6 42 56 4
 0.05  2.0    1 28 30 15
end data.
if (npc=0) npc=n/(dfh+1).
*initialize values.
compute zero=0.00000001.
compute lambda=dfh*fvalue.
compute rho2=lambda/(lambda+N).
compute epsilon=(Fvalue-1)/(Fvalue+dfe/dfh).
compute omega2=(Fvalue-1)/(Fvalue+(dfe+1)/dfh). /*Fowler(1985).
*compute omega22=(Fvalue-1)/(Fvalue+N/dfh).
compute eta2=Fvalue/(Fvalue+dfe/dfh).
compute f=sqrt(lambda/n).
compute f_alpha=idf.f(1-alpha,dfh,dfe).
compute pvalue=1-cdf.f(fvalue,dfh,dfe).
compute powa=1-ncdf.f(f_alpha,dfh,dfe,lambda).
compute RMSSE=sqrt(lambda/(dfh*npc)).
compute ylambda=lambda.
if ylambda< 10 ylambda=10.
compute stepl=ylambda/20.

do repeat cumpd=0.05, 0.95/xrmsse=uRMSSE lRMSSE/xf=uf lf
                /xpowa=upowa lpowa/ xrho2=urho2 lrho2.
compute xlambda=ylambda.
if (xlambda<zero) xlambda=zero.
compute cumpa=ncdf.f(fvalue,dfh,dfe,xlambda).
compute dir=1.
if (cumpa<cumpd)  dir=-1.
do if (dir=-1).
loop  if  (cumpa<cumpd and xlambda>zero).
  compute xlambda=xlambda-stepl.
  if (xlambda<zero) xlambda=zero.
  compute cumpa=ncdf.f(fvalue,dfh,dfe,xlambda).
end loop.
else. 
loop  if  (cumpa>=cumpd and xlambda>0).
  compute xlambda=xlambda+stepl.
  compute cumpa=ncdf.f(fvalue,dfh,dfe,xlambda).
end loop.
end if.

*begin loop for interval halving.
compute dir=1.
if (cumpa<cumpd)  dir=-1. 
compute nlambda=xlambda.
compute intv=stepl*2.
compute cumpdiff=abs(cumpa-cumpd).
compute zero=zero/10.
loop if (cumpdiff>=.00001 and nlambda>zero).
  compute  intv=intv*.5.
  compute  nlambda=nlambda +dir*intv*.5.
  if (nlambda<zero) nlambda=zero.
*compute p-value .
  compute cumpa=ncdf.f(fvalue,dfh,dfe,nlambda).
  compute cumpdiff=abs(cumpa-cumpd).
  do if (cumpa<cumpd).
    compute  dir=-1.
    else .
    compute dir= 1.
  end if.
end loop.
compute xRMSSE=sqrt(nlambda/(dfh*npc)).
compute xf=sqrt(nlambda/n).
compute xpowa=1-ncdf.f(f_alpha,dfh,dfe,nlambda).
compute xrho2=nlambda/(nlambda+n).
end repeat.

format cumpa alpha (f5.3) cumpdiff(f8.6).
* adjusted lambda.
compute   lambda2=lambda*(dfe-2)/dfe-dfh.     /* kano */ /* Fleishman(1981) */
if (lambda2 < zero) lambda2=zero.
*compute unrho2=lambda2/(lambda2+n).
compute power2=1-ncdf.f(f_alpha,dfh,dfe,lambda2).
compute esize=sqrt(lambda2/n).

*compute zeta=dfh*fvalue*(dfe-1)/(dfe-dfh)/(dfh+dfe+1).
*compute rho2un=zeta/(1+zeta).
*.
compute num=$casenum.
format num(f3.0).
format pvalue (f5.4).
format  lpowa upowa powa power2 alpha rmsse lRMSSE urmsse(f5.3) n(f6.0) dfh(f3.0) dfe(f4.0).
format f lf uf esize (f5.3).
format fvalue(f10.4).
format eta2 rho2 urho2 lrho2  epsilon omega2 (f4.3).
report format=list/var=
        num 'no' (3) 
        alpha 'alpha' 'level'(5)
        fvalue 'f' 'value' (7)
        dfh 'dfh' (3)
        dfe 'dfe' (4)
        n 'n' 'total' (5) 
        epsilon 'partial' '2' 'epsilon'(7)
        omega2 'partial' '2' 'omega ' (7)
        eta2 'partial' '2' 'eta ' (7)
        lrho2 'lower' '2' 'rho '(5)
        urho2 'upper' '2' 'rho '(5)
      /title="accounted variance".

     /*   rho2 '2' 'rho'(4) */

report format=list/var= 
       num 'no' (3) 
        pvalue'p' 'value'(5)
       f 'effect' 'size' 'f' (6)
        esize 'adjust' 'ed' 'f' (6)lf 'lower' 'bound' 'f' (5) uf  'upper' 'bound' 'f' (5) 
     rmsse 'RMSSE'(5)  lRMSSE 'lower' 'bound' 'RMSSE'(5)  uRMSSE 'upper' 'bound' 'RMSSE'(5) 
       powa 'power'(5)  power2 'adjust' 'ed' 'power'(6)
       lpowa  'lower' 'bound' 'power'(5) upowa 'upper' 'bound' 'power'(5)
      /title="90% confidence intervals of effect size and power analysis (fixed effects ANOVA)"
.
restore.

.